;**** DEFINITIONS ******************************

;**** CLOCK
.equ		CLOCK	=  14745600

;**** BAUDRATE
.equ		BAUD	= 9600
.equ		UBRRVAL = CLOCK/(BAUD*16)-1

;**** REGISTERS
.def i = r16
.def j = r17
.def k = r18
.def steph = r19
.def stepl = r20
.def stephb = r21
.def steplb = r22
.def stepnum = r23
.def color = r24

;**** INTERRUPT VECTORS
.org 0x000
rjmp init
.org INT0addr
rjmp trigger
.org OC1Aaddr
rjmp step
.org OVF1addr
rjmp ovf
.org OVF0addr
rjmp rstuart
.org URXCaddr						;USART Rx Complete Vektor
rjmp rx 

init:
cli

;**** STACK
ldi i,LOW(RAMEND)
out SPL, i
ldi i,HIGH(RAMEND)
out SPH, i

;**** I/O
ldi i, 0b00111111
out DDRC, i
ldi i, 0b00000011
out DDRB, i

clr i
out PORTB, i
out PORTB, i

;**** SRAM
	ldi	i, 0b10010001						;0x100-0x1FF mit anfangsmuster laden
	ldi	ZH, 0x01
	ldi	ZL, 0x00
init_sram:
	st	Z, i
	subi	ZL, -1
	brne	init_sram
	subi	ZH, -1
	cpi	ZH, 0x02
	brne	init_sram
	ldi	ZH, 0x01
	ldi	YH, 0x01

;**** EXTERNAL INTERRUPT INT0
ldi i, (3<<ISC00)
out MCUCR, i
ldi i, (1<<INT0)
out GICR, i

;**** TIMER0 and TIMER1
ldi i, (1<<OCIE1A)|(1<<TOIE1)|(1<<TOIE0)
out TIMSK, i
ldi i, 0
out TCCR1A, i
ldi i, (3<<CS10)
out TCCR1B, i
ldi i, (5<<CS00)
out TCCR0, i
clr i
out TCNT1H, i
out TCNT1L, i
clr i
out OCR1AH, i
out OCR1AL, i

;**** USART
ldi	i, LOW(UBRRVAL)				;rxb not empty int./txb empty int.
out	UBRRL, i
ldi	i, HIGH(UBRRVAL)
out	UBRRH, i
ldi   i, (1<<URSEL)|(1<<UCSZ1)|(1<<UCSZ0)
out   UCSRC, i
ldi	i, (1<<RXEN)|(1<<RXCIE)
out	UCSRB, i

sei

ldi color, 0b00000000
rcall setcolor

;##### LOOP ##############################################################################

loop:

rjmp loop


;##### TRIGGER ################################################################################

trigger:
push i
in i, SREG
push i

in steplb,TCNT1L
in stephb,TCNT1H
clr i
out TCNT1H, i
out TCNT1L, i

cpi steph, 4
brlo trigger_pass

clc
ror stephb
ror steplb
clc
ror stephb
ror steplb
clc
ror stephb
ror steplb
mov steph, stephb
mov stepl, steplb
clc
ror stephb
ror steplb
add stepl, steplb
adc steph, stephb
clc
ror stephb
ror steplb
clc
ror stephb
ror steplb
sub stepl, steplb
sbc steph, stephb

out OCR1AH, steph
out OCR1AL, stepl

ldi ZL, 0x00
clr i
out PORTB, i
out PORTC, i

trigger_pass:
pop i
out SREG, i
pop i
reti


;##### STEP ################################################################################

step:
push i
in i, SREG
push i

cpi ZL, 42
brsh step_off

ld color, Z
rcall setcolor
inc ZL

add stepl, steplb
adc steph, stephb

out OCR1AH, steph
out OCR1AL, stepl

pop i
out SREG, i
pop i
reti

step_off:
clr color
rcall setcolor

pop i
out SREG, i
pop i
reti

;##### OVF ###########################################################################################

ovf:
push i
in i, SREG
push i

ldi color, 0b00000001
rcall setcolor

pop i
out SREG, i
pop i
reti

;##### RSTUART ###########################################################################################

rstuart:
push i
in i, SREG
push i

clr YL

pop i
out SREG, i
pop i
reti

rx:
push i
in i, SREG
push i

clr i
out TCNT0, i

in i, UDR					;get data
st Y, i
inc YL

cpi YL, 42
brne rx_end
clr YL

rx_end:
pop i
out SREG, i
pop i
reti

;##### SETCOLOR ###########################################################################################

setcolor:
clr j
clr k

;hyperblue
ldi i, 0b10000000
and i, color
breq setnohb
ori j, 0b00000001
setnohb:

;blue
ldi i, 0b01000000
and i, color
breq setnob
ori k, 0b00000010
setnob:

;turqouis
ldi i, 0b00100000
and i, color
breq setnot
ori j, 0b00001000
setnot:

;green
ldi i, 0b00010000
and i, color
breq setnog
ori j, 0b00000010
setnog:

;amber
ldi i, 0b00001000
and i, color
breq setnoa
ori j, 0b00010000
setnoa:

;red
ldi i, 0b00000100
and i, color
breq setnor
ori j, 0b00000100
setnor:

;deepred
ldi i, 0b00000010
and i, color
breq setnodr
ori k, 0b00000001
setnodr:

;hyperred
ldi i, 0b00000001
and i, color
breq setnohr
ori j, 0b00100000
setnohr:

out PORTB, k
out PORTC, j
ret