;
; 1kB roguelike using an arduino and 0.96" OLED
; 

; Author : Radoslaw Sadowski
;

.include "m328Pdef.inc"

.equ speed = 19200
.equ cpu = 16000000
.equ rst = 0
.equ dc =1
.equ cs = 2
.equ bittimer = (cpu/speed/16)-1

.macro mcommand 
	ldi r20, @0
	rcall command
.endmacro
	
;;;;;;;;; variables ;;;;;;;;;;;
.dseg
buffer: .byte (64*128/8)
map:	.byte 8		; 8bit x 8bit


;;;;;;;;;; main ;;;;;;;;;;;;;;;
.cseg
.org 0x0000
	rjmp reset


reset:
	ldi r16, LOW(RAMEND)
	ldi r17, HIGH(RAMEND)
	sts SPL, r16
	sts SPH, r17

	rcall setup_uart
	rcall setup_spi
	rcall OLED_init


	rcall clear_buffer
	rcall draw_map
	rcall draw_player

	rcall display

loop:
	rjmp loop
;;;;;;;;;;;;;;;;;;;;;;;;;

;;;;;;;;;;;;;;;;;;;;;;;;


; Display routine from adafruit1306 library
display:
	mcommand 0x21
	mcommand 0x00
	mcommand 127
	mcommand 0x22
	mcommand 0x0
	mcommand 0x7

	sbi PORTB, 2 ;cs high
	sbi PORTB, 1 ;dc low
	cbi PORTB, 2 ;cs high

	ldi r23,4
	ldi r22,0
	ldi r21,0
	ldi YL, low(buffer)
	ldi YH, high(buffer)

	send_buffer:
	ld r20, Y+
	rcall spi_send
	inc r21
	brne send_buffer
	inc r22
	cpse r22,r23
	brne send_buffer

	sbi PORTB, 2 ;cs

	ret
;;;;;;;;;;;;;;;;;;;;;;;
spi_send:
	out		spdr, r20
wait_sprs:
	in		r16, SPSR
	sbrs	r16, SPIF
	rjmp	wait_sprs
	ret
;;;;;;;;;;;;;;;;;;;;;;
setup_spi:
	ldi		r16, (1<<5)|(1<<3)|(1<<rst)|(1<<cs)|(1<<dc)
	out		DDRB, r16
	ldi		r16, (1<<SPE)|(1<<MSTR)
	out		SPCR,r16
	ldi		r16, (1<<SPI2X)
	out		SPSR, r16
	ret
;;;;;;;;;;;;;;;;;;;;;;
command:
	sbi		PORTB, cs ;cs high
	cbi		PORTB, dc ;dc low
	cbi		PORTB, cs ;cs low
	rcall	spi_send
	sbi		PORTB, cs; cs high
	ret
;;;;;;;;;;;;;;;;;;;;;;;;
tx_uart:
	lds		r17, UCSR0A
	sbrs	r17, UDRE0
	rjmp	tx_uart
	sts		UDR0, r16
	ret
;;;;;;;;;;;;;;;;;;;;;;;;;
draw_map:
	ldi		xl, low(buffer)
	ldi		xh, high(buffer)
	ldi		yl, low(buffer)
	ldi		yh, high(buffer)
	ldi		zl, low(2*main_map)
	ldi		zh, high(2*main_map)
	movw	r25:r24,z

	ldi		r21, 128
	ldi		r22,0				; y tile num
	ldi		r18, 8				; y tile num
tile_no:
	movw	y,x	
	movw	z,r25:r24				; load map
	lpm		r16, z				; bit map/line value
	adiw	r25:r24, 1
	ldi		r17, 8				; 8 bit/tiles per line
draw_line:	

	lsl		r16
	brcs	draw_wall
draw_floor:
	ldi		zl, low(2*floor)
	ldi		zh, high(2*floor)
	lpm		r19, z
	rcall	draw_tile
	rjmp	end_tile
draw_wall:
	ldi		zl, low(2*wall)
	ldi		zh, high(2*wall)
	lpm		r19, z
	rcall	draw_tile
end_tile:

	dec		r17
	brne	draw_line

	rcall	next_line

	dec		r18
	brne	tile_no
	ret
;;;;;;;;;;;;;;;;;;;;;;;;;;
draw_player:
	ldi		yl, low(buffer)
	ldi		yh, high(buffer)
	movw	x, y
	ldi		zl, low(2*player_pos)
	ldi		zh, high(2*player_pos)
	lpm		r16, z+
	lpm		r17, z
	ldi		zl, low(2*player_sprite)
	ldi		zh, high(2*player_sprite)
	lpm		r19, z+
	ldi		r18, 8
	ldi		r21, 0

buf_pos_y:
	dec		r17
	breq	y_set
	rcall	next_line
	rjmp	buf_pos_y
y_set:
	mul		r16,r18
	add		xl, r0
	adc		xh, r1
	movw	y,x
	rcall	draw_tile
	ret
;;;;;;;;;;;;;;;;;;;;;;;;;;
draw_tile:
	ldi		r20, 8
fill_tile:
	st		y+, r19
	lpm		r19, z+
	dec		r20
	brne	fill_tile
end_draw:
	ret
;;;;;;;;;;;;;;;;;;;;;;;;;
next_line:
	adiw	x, 60			; increase buffer address by 128, new line
	adiw	x, 60
	adiw	x, 8
	ret
;;;;;;;;;;;;;;;;;;;;;;;;;
setup_uart:
	ldi		r16, low(bittimer)
	sts		UBRR0L, r16
	ldi		r16, high(bittimer)
	sts		UBRR0H, r16
	ldi		r16, (3<<UCSZ00)
	sts		UCSR0C, r16
	ldi		r16, (1<<RXEN0)|(1<<TXEN0)
	sts		UCSR0B, r16
	ldi		r16, 0b01010000
	ret
;;;;;;;;;;;;;;;;;;;;;;;;;
clear_buffer:

	ldi		xl, low(buffer)
	ldi		xh, high(buffer)
	ldi		r16, 0x00

	ldi		r22,4
	ldi		r20,0
	ldi		r21,0
	cbuffer:
	st		x+, r16
	inc		r20
	brne	cbuffer
	inc		r21
	cpse	r21, r22
	rjmp	cbuffer
	ret
;;;;;;;;;;;;;;;;;;;;;;;;;
print_buffer:
	ldi xl, low(buffer+1023)
	ldi xh, high(buffer+1023)
	ldi r22,4
	ldi r20,0
	ldi r21,0
	pbuffer:
	ld r16, x+
	rcall tx_uart
	inc r20
	brne pbuffer
	inc r21
	cpse r21, r22
	rjmp pbuffer
	ret
;;;;;;;;;;;;;;;;;;;;;;;;;

;;;;;;;;;;;;;;;;;;;;;;;;;

; OLED sequence from adafruit 1306 library

OLED_init:
	sbi PORTB, rst		; rst high

    ldi  r18, 21		; delay 1ms
    ldi  r19, 199
L1: dec  r19
    brne L1
    dec  r18
    brne L1

	cbi PORTB, rst		;rst low

    ldi  r18, 208		; delay 10ms
    ldi  r19, 202
L2: dec  r19
    brne L2
    dec  r18
    brne L2

	sbi PORTB, rst		; rst high

	mcommand 0xae
	mcommand 0xd5
	mcommand 0x80
	mcommand 0xa8
	mcommand 63
	mcommand 0xD3
	mcommand 0x0
	mcommand 0x40
	mcommand 0x8d
	mcommand 0x14
	mcommand 0x20
	mcommand 0x00
	mcommand (0xa8|0x1);
	mcommand 0xc8
	mcommand 0xDA
	mcommand 0x12
	mcommand 0x81
	mcommand 0xcf
	mcommand 0xd9
	mcommand 0xf1
	mcommand 0xdb
	mcommand 0x40
	mcommand 0xa4
	mcommand 0xa6
	mcommand 0x2e
	mcommand 0xaf
	ret
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
; hard coded tiles
wall:			.db 0xff, 0xff, 0xff, 0xff, 0xff, 0xff, 0xff, 0xff
floor:			.db 0x00, 0x00, 0x00, 0x00, 0x00, 0x00, 0x00, 0x00
main_map:		.db 0xff, 0x81, 0x81, 0x1, 0x81, 0x81, 0x81, 0xfb
player_sprite:	.db 0x0e,0x1f,0xff,0xfb, 0xfb, 0xfb, 0x37, 0xfa
player_pos:		.db 4, 4
enemy_sprite:	.db 0x18, 0x18, 0x18, 0x18, 0x18, 0x18, 0x18, 0x18