TITLE Einstein Silicon Disc GAL 1
PATTERN A
REVISION 1.0
AUTHOR TONY BREWER
COMPANY -
DATE 6/5/13

;
; 2025-09-21
; Active levels moved to the pin names, as they should be.
; Pin comments added.

CHIP ESD1 GAL16V8

	A7 A6 A5 A4 A3 A2 A1 A0	; i/o address lines
	/IORQ
	GND
	/M1
	/WR
	DD1
	/SWL	; clock data bus into Lower  sector address latch
	/SWH	; clock data bus into Higher sector address latch 
	/DRW	; data read/write
		;
	/S8	; 1-bit multiplexer output
	R1 	; 1-bit multiplexer input
	R2 	; 1-bit multiplexer input

	VCC

; Intermediate expressions:
;
; These ports hold the sector and offset address bits.
; Presumably if the sectors had 256 bytes,
; you could have 256 x 256 x 256 = 16 Mbytes
;
;
; XXF8H          Output low byte of sector number
; XXF9H          Output high byte of sector number
; NNFAH          Input or output data byte

port_F8		= A7 *  A6 *  A5  * A4 *  A3 * /A2 * /A1 * /A0
port_F9		= A7 *  A6 *  A5  * A4 *  A3 * /A2 * /A1 *  A0
port_FA		= A7 *  A6 *  A5  * A4 *  A3 * /A2 *  A1 * /A0

io		= IORQ *  /M1	; not M1 active, that would be interrupt acknowledge cycle.

EQUATIONS

	SWL	= port_F8 * io * WR	;OUT 0F8H

	SWH	= port_F9 * io * WR	;OUT 0F9H

	DRW	= port_FA * io		;IN/OUT 0FAH

	S8	= /R1 *  DD1		;DRAM A8 row address
		+ /R2 * /DD1		;DRAM A8 column address