TITLE Einstein Silicon Disc GAL 2
PATTERN A
REVISION 1.0
AUTHOR TONY BREWER
COMPANY -
DATE 6/5/13

;
; 2025-09-21
; Active levels moved to the pin names, as they should be.
; Pin comments added.
;
; Refreshing is /CAS-before-RAS because 
; the Z80 provides only 7 bit refresh row address
; and the 41256 needs 9 bits.
;
;
;
CHIP ESD2 GAL16V8

	R6 R5 R4 R3 
	/DRW	;
	/DD1	;
	/DD2	;
	/MREQ	; 
	/IORQ	; unused
	GND
	/M1	; unused
	/WR	; unused
	/RD 	; unused
		; 4 outputs
	/RAS 
	/CAS
	/AS1	; enables output of IC4 (74LS374) Lower byte of Sector address
	/AS2	; enables output of IC5 (74LS244) A8-14 from Z80 register B during I/O cycle
		;                                 plus bit 0 of Higher byte of Sector address

	SYSCLK 	; unused
	/RFSH
	VCC
;
; Intermediate terms:
;
first_256kB	=  /R6 * /R5 * /R4 * /R3		; (R6-R3=0000)
second_256kB	=  /R6 * /R5 * /R4 *  R3		; (R6-R3=0001)

EQUATIONS

	RAS	= DRW  * first_256kB			;Data read/write for first 256kB (R6-R3=0000)
		+ MREQ * RFSH				;Refresh, /CAS-before-RAS

	CAS	= DD2  * first_256kB		 	;Data read/write for first 256kB (R6-R3=0000)
		+        RFSH				;Refresh, /CAS-before-RAS

	AS1	= /DD1					;Address strobe 1 for DRAM A0-A7 row address

	AS2	= DD1					;Address strobe 2 for DRAM A0-A7 column address

; DD1 is DRW delayed (by two 74x04 inverters and RC delay)
; DD2 is DD1 delayed (by two 74x04 inverters and RC delay)
;
; A 512KB Silicon Disc is possible by connecting two 256KB PCBs, 
; with a modified GAL 2 on one of the boards with R6-R3=0001
;
; More than 512KB is also feasible, but the current version 
; of the ROM (v1.1) only supports a 256KB Silicon Disc
;