nam CS09 IDE controller boot source

****************************************
* Bootstrap module for OS9
*
*** loads Os9Boot file from disk
*
* uses IDE interface using Programmed IO
*
* reads 256 from 512-byte sectors!
* by reading every other byte (low byte from 16-bit transfer)
*
*
* (c) 2025-2026 Roelof van Silfhout
*
****************************************

 use defsfile

 ttl Boot Module

Type set Systm+Objct
Revs set ReEnt+2

 mod BTEND,BTNAM,Type,Revs,BootST,BTSTA

BTNAM fcs "Boot"
 fcb 1 edition

*********************************************************************
*
* Static Storage
*
*
 org 0

V.BUF rmb 2
V.BootSZ rmb 2 Bootfile size (in bytes)
V.SrtLSN rmb 3 Bootfile starting sector as read from LSN0

BTSTA equ .

*********************************************************
* Boot
*
* Output: D = Size of bootfile loaded
* X = Address where the file is loaded in memory
*
* if error: set carry bit and fill B with error type
*
* IDE drive has 512-byte physical sector Size
* whereas OS9 relies on 256-byte logical sector size
* by just doing low byte transfers we skip every other
* byte from each 512-byte sector
*
BootST leas <-BTSTA,s create space on stack
* Y gets to point at base of space on stack
 tfr s,y Point Y to static memory on stack
 

 
* reserve space for LSN0
 ldd #256 Get buffer for LSN 0 read
 os9 F$SRqMem returns address of buffer in U, D has rounded size to 256 byte
 bcs BOOTER Problem no mem
 stu V.BUF,y Save buffer addr to stack space for use
*
**** Read LSN0 sector
*
 clrb
 ldx #0 Get sector zero, LSN0
 lda #1 read 1 sector only, just LSN0

 bsr READSK read LSN0 from IDE disk
 bcs BOOTER Branch if can't read
 ldu V.BUF,y restore u to start of buffer
 ldd DD.BSZ,u Get bootstrap size (in bytes)
 beq BOOT2 branch if no boot file
 std V.BootSZ,y save byte count bootfile

* non zero size bootfile found go and load it
* note we assume LSN number is within 16-bit
* boundary (eventhough LSN are 24-bit)
 ldd DD.BT,u Get boot starting LSN number
 std V.SrtLSN,y save start LSN
 lda DD.BT+2,u get the 3rd byte
 sta V.SrtLSN+2,y save
 
* return buffer used for LSN0
 ldd #256
 os9 F$SRtMem return initial LSN0 buffer U has begin address
 bcs BOOTER
*
**** Now get space for bootfile
*
 ldd V.BootSZ,y Get bootstrap file size (in bytes)
 OS9 F$SRqMem Get boot memory, U gets start address
* D has actual amount rounded up to 256 bytes
* or, in other words, A has the # of sectors to read!
 bcs BOOTER Branch if none
 stu V.BUF,y save start of memory where to put bootfile

*
**** Read all Sectors
* 
* Note: A has # sectors to read already, from F$SRqMem
 ldb V.SrtLSN,y
 ldx V.SrtLSN+1,y get first sector number
 bsr READSK read first sector with bootfile data from IDE disk
 bcs BOOTERR Branch if error

* load return parameters and return
 ldx V.BUF,y ptr to memory location where bootfile starts
BOOT2 ldd V.BootSZ,y get size of bootfile
BOOTER leas <BTSTA,s clean up stack
 rts
 
booter4 ldb #E$NotRdy device not ready
 bra BOOTER
BOOTERR ldb #E$Read flag read error
 bra BOOTER

delay ldb #64  set up a delay counter
del decb decrement the delay count
 bne del  hang in there for the count
 rts
 
*************************************************************
*
**** Read Sector Command - READSK
*
* Input: B;X = Physical LBA Number (24-bits)
*        A: # sectors
* U = Buffer address for data storage
* Y = Ptr To Static Storage
*
* Output: 
* required number of physical sectors read in buffer with
*
* U = first empty location in buffer, ready for more if needed
* B destroyed
*
* Error: Cc=Set, B=Error Code
*
READSK pshs d,x,u save registers

**** Initialise/check IDE controller
* check controller readiness
 ldx #A.IDEbase get base address IDE controller
 clr dmaltc,x disable everything

* place LBA number into IDE registers
* Note: we could add partinioning here making use of the fact
* that we still have 4-bits left of the 28-bit LBA address
* these bits go in ideadr3,x now set at 0
 ldb #IDE_LBA force lBA disk addressing and select Master drive
 stb ideadr3,x 
 ldb idecmst,x  get status
 cmpb #(IDERDY+IDEDSC) idle?
 bne ider2 if not ready quit with error code
 ldb #H.RST
 stb idecmst,x restore drive
 lbsr delay wait
isnrdy lbsr delay
 ldb idecmst,x check if done
 bitb #IDEBSY
 bne isnrdy
rdret1 ldb #1
 stb idescnt,x sector count 
 ldb 3,s get save x register which holds lower 8bit LBA
 stb ideadr0,x put in IDE register
 ldb 2,s get higher bits
 stb ideadr1,x and save
 ldb 1,s and the highest 8-bits of 24-bit LBA
 stb ideadr2,x and save
 ldb #IDE_LBA force lBA disk addressing and select Master drive
 stb ideadr3,x check header
 
* start PIO data transfer and monitor end of transfer interrupt bit
 ldb #H.PRD PIO data read 
 stb idecmst,x issue command
 nop
* waiting loop for transfer to complete
d256lp ldb idecmst,x get status
 andb #IDEBSY busy?
 bne d256lp wait if so
d256ld ldb idecmst,x get status
 andb #IDEDRQ check if data is ready
 beq d256ld loop if not
 
 ldw #256 fixed sector size
 tfm x,u+ transfer all bytes w/o incrementing x
 
 ldb idecmst,x check status
 andb #IDEERR+IDEDRQ leave error and datarequest bits
 beq rdret return if no error
ider2 puls u,x,d buffer now in u
 ldb #E$NotRdy load error in back
 rts
 
rdret deca more sectors?
 beq rdend
 inc 3,s increment LBA no.
 bne rdret1
 inc 2,s deal with overflow
 bne rdret1
 inc 1,s 
 bra rdret1

rdend puls u,x,d
 clrb no errors
 rts
 
 emod

BTEND equ *

 end